Instructions

Copy and paste the below code into a compatible MUSH or MUX.

MUSHCode for Police Motorcycle

@create Police Motorcycle
@lock Police Motorcycle==me
@Desc Police Motorcycle=[switch(u(me/mounted),0,{%r[u(outside)]%r[switch(u(me/siren),0,,1,{The sirens are blazing loudly and the lights are flashing madly!%r})]%r},1,{%r[u(outside)]%r[switch(u(me/siren),0,,1,{The sirens are blazing loudly and the lights are flashing madly!%r})] %rCurrently mounted atop [name(me)] is [v(rider)].%r%r[u(*[v(rider)]/desc)]%r})]
@Idesc Police Motorcycle=%r[get_eval(me/inside)]%r[switch(u(me/siren),0,,1,{The sirens are blaring loudly and the lights are flashing madly!%r})]%r%rThe [name(me)] is currently at [name(here)]. [setq(0,iter(lcon(here),switch(type(##),player,switch(hasflag(##,connected),1,##))))][setq(1,setdiff(iter(lcon(here),switch(and(strmatch(type(##),T*),not(hasflag(##,DARK))),1,##)),%!))]You can scan [switch(words(r(0)),0,nobody,1,name(r(0)),iter(rest(r(0)),name(##)%vz) and [name(first(r(0)))])] walkin' the area, and see [switch(words(r(1)),0,nothin' important,1,name(r(1)),iter(rest(r(1)),name(##)%vz) and [name(first(r(1)))])] around ya.%r[switch(u(me/siren),0,,1,{The sirens are blaring loudly and the lights are flashing madly!%r})]%r%r('MChelp' gives options and instructions.)%r
@Listen Police Motorcycle=*
@Inprefix Police Motorcycle=On the street,
@Prefix Police Motorcycle=From atop the [name(me)],
@Infilter Police Motorcycle=*has arrived.,*has left.,Dropped.,*whispers to*
@Filter Police Motorcycle=*has arrived.,*has left.,Dropped.,*whispers to*
@VZ Police Motorcycle=,
@Lalias Police Motorcycle=leave;exit;out;o;dismount
@Ealias Police Motorcycle=Mount Bike;Mount cycle;mount;mb
@Oenter Police Motorcycle=slides a leg over the [name(me)] and takes a seat on it.
@Oxenter Police Motorcycle=slides a leg over the [name(me)] and takes a seat on it.
@Fail Police Motorcycle=It's too heavy to lift.
@Ofail Police Motorcycle=strains, trying to lift the [name(me)].
@Efail Police Motorcycle=If you really want to steal this [name(me)], contact a judge.
@Omove Police Motorcycle=[switch(u(me/siren),0,{thunders in with [setq(0,iter(lcon(me),switch(type(##),player,switch(hasflag(##,connected),1,##))))][switch(words(r(0)),0,no one,1,name(r(0)),2,name(first(r(0))) and [name(rest(r(0)))],iter(rest(r(0)),name(##)%va) and [name(first(r(0)))])] riding on top.},1,{thunders in with [setq(0,iter(lcon(me),switch(type(##),player,switch(hasflag(##,connected),1,##))))][switch(words(r(0)),0,no one,1,name(r(0)),2,name(first(r(0))) and [name(rest(r(0)))],iter(rest(r(0)),name(##)%va) and [name(first(r(0)))])] riding on top with sirens blaring and lights flashing!})]
@Aenter Police Motorcycle=@unlock/enter me;@emit %N unlocks the seat lock as %s mounts the [name(me)].;&mounted me=1;&rider me=%N;@name me=[u(bikename)] ([v(rider)])
@Aleave Police Motorcycle=@lock/enter me=+Name:DPD Badge;@emit %N secures the seat lock as %s dismounts.;&mounted me=0;&rider me=no one;@name me=[u(bikename)]
@Oxleave Police Motorcycle=swings a leg off the [name(me)] and hops off.
@Enter Police Motorcycle=You slide a leg over the [name(me)] and take a seat.
@Leave Police Motorcycle=You swing a leg off the [name(me)] and hop off.
@Oleave Police Motorcycle=slips a off the [name(me)] and hops off.
@Oxtport Police Motorcycle=roars loudly and screechs off, sending a hail of pebbles behind it.
@lock/UseLock Police Motorcycle=+Name:DPD Badge
&START Police Motorcycle=$kickstart:@switch [u(me/engine)]=0,{@emit %N raises up in the seat and stomps down on the [name(me)]'s starter. The engine comes to life with a deafening roar and revs loudly as %N guns it several times.;&engine me=1},{@pemit %#=The engine is already running.}
&STOP Police Motorcycle=$stop:@switch [u(me/engine)]=0,{@pemit %#=[u(me/engerror)]},1,{@emit %N relaxes on the [name(me)] as its engine slowly dies down and becomes silent.;&engine me=0},2,{@emit %N slams on the brakes to the [name(me)], skidding the motorcycle to a halt and cutting the engine in one fluid motion.;&engine me=0}
&ENGINE Police Motorcycle=0
&ENGERROR Police Motorcycle=The engine isn't on.
&DRIVE Police Motorcycle=$dri* *:@switch [u(me/engine)]=0,{@pemit %#=[u(me/engerror)]},1,{@switch [u(me/siren)]=0,{@emit %N kicks the [name(me)] into gear and the bike tears off with a squeal of rubber.},1,{@emit %N kicks the [name(me)] into gear and the bike tears off with a squeal of rubber, sirens blaring and lights flashing.};&engine me=2;@force me=[iter(%1,secure(move ##))]},2,{@switch [u(me/siren)]=0,{@emit %N roars off on the [name(me)].},1,{@emit %N roars off on the [name(me)] with sirens blaring and lights flashing.};@force me=[iter(%1,secure(move ##))]}
&ENGIDLE Police Motorcycle=$idle:@switch [u(me/engine)]=0,{@pemit %#=[u(me/engerror)]},1,{@emit %N drops the [name(me)] into neutral and the engine drops from a loud roar to a softly purring idle.},2,{@pemit %#=You need to brake first.}
&BRAKE Police Motorcycle=$brake:@switch [u(me/engine)]=0,{@pemit %#=[u(me/engerror)]},1,{@pemit %#=The [name(me)] is idling.},2,{@emit %N turns the [name(me)] sideways and slams on the brakes, bringing the motorcycle to a screeching halt!;&engine me=1}
&SBRAKE Police Motorcycle=$sbrake:@switch [u(me/engine)]=0,{@pemit %#=[u(me/engerror)]},1,{@pemit %#=The [name(me)] is idling.},2,{@emit %N gradually applies the brakes on the [name(me)] and the motorcycle slows to a halt.;&engine me=1}
&FOLLOW_DO Police Motorcycle=$stop follow:&follow me;@pemit %#=Stopped following.
&FOLLOW_DO2 Police Motorcycle=$follow *:&follow me=[num(%0)];@wait 1=@pemit %#=Following [name(v(follow))].
&SHOULDFOLLOW Police Motorcycle=[gt(member(v(follow),%#),0)]
&CHECK_FOLLOW Police Motorcycle=^* has left.:@switch [and(member(%#,v(follow)),member(lcon(me),owner(me)))]=1,{go [name(extract(lexits(here),match(iter(lexits(here),loc(##)),%l),1))]}
&SCAN Police Motorcycle=$scan:look
&SCAN2 Police Motorcycle=$scan *:look %0
&OUTSIDE Police Motorcycle=%r[space(5)]This is your basic DPD Patrol Motorcycle: a modified black and white 1997 Harley Davidson with the Denver state emblem on the sides of the fuel tank and Denver Police stenciled underneath it along with the motto "To Protect and To Serve". It is reinforced, finely tuned, and well-maintained. Three separate antennas pertrude from rear of the cycle. A single spotlight attached to the left side accompanies the blue-and-red emergency lights mounted to each side at the front, as well as a sole blue-and-red light on a pole in the back of the motorcycle. [u(me/engdesc)]
&INSIDE Police Motorcycle=%r[space(5)]You are seated atop a DPD Patrol Motorcycle. Its construction and engine are heavily reinforced, and finely tuned. The dash is crowded with a radio and other equipment, including the usual gauges. [u(me/engdesc)]
&INME Police Motorcycle=[gt(member(lcon(me),%#),0)]
&ENGDESC Police Motorcycle=[switch(u(me/engine),0,{The engine on the large motorcycle is not running.},1,{The motorcycle's large engine is purring softly in neutral.},2,{The large motorcycle is in gear, engine roaring loudly.})]
&FLASH Police Motorcycle=$flash:@switch [v(siren)]=1,{@pemit %n=The sirens are already on.},0,{@emit The lights on [name(me)] flash once in warning.}
&LIGHTS Police Motorcycle=0
&LIGHTS_ON Police Motorcycle=$lights on:@switch [v(lights)]=1,@pemit %#=The red-and-blue lights are already on.,0,{@pemit %#=You turn on the red-and-blue lights!;@emit The red-and-blue lights on [name(me)] suddenly turn on!;&lights me=1;@tr me/lights_sound}
&LIGHTS_OFF Police Motorcycle=$lights off:@switch [v(lights)]=0,@pemit %#=The red-and-blue lights are already off.,1,{@pemit %#=You turn off the red-and-blue lights.;@emit The red-and-blue lights on [name(me)] stop flashing.;&lights me=0;@halt me}
&LIGHTS_SOUND Police Motorcycle=@wait 3=@emit The red-and-blue lights on [name(me)] flash repeatedly in warning!;@wait 100=@tr me/lights_sound
&SIREN Police Motorcycle=0
&SIREN_ON Police Motorcycle=$siren on:@switch [v(siren)]=1,@pemit %#=The siren is already on.,0,{@pemit %#=You turn on the sirens!;@emit The sirens on [name(me)] suddenly turn on!;&siren me=1;@tr me/siren_sound}
&SIREN_OFF Police Motorcycle=$siren off:@switch [v(siren)]=0,@pemit %#=The siren is already off.,1,{@pemit %#=You turn off the sirens.;@emit The sirens on [name(me)] fall silent.;&siren me=0;@halt me}
&SIREN_SOUND Police Motorcycle=@wait 5=@emit The sirens and lights on [name(me)] flash repeatedly in warning!;@wait 100=@tr me/siren_sound
&STATION Police Motorcycle=$station:@emit [switch(u(me/siren),0,{[name(me)] drives off, engine purring softly.},1,{[name(me)] tears off, sirens blaring and lights flashing!})];@force me=home
&RIDER Police Motorcycle=no one
&MOUNTED Police Motorcycle=0
&HELP Police Motorcycle=$mchelp:@pemit %#=%r[repeat(-,78)]%r[center(Denver Police Department,78)]%r[center(Patrol Motorcycle Help,78)]%r[repeat(-,78)]%r%r[space(6)][ljust(kickstart,21,.)]Stomps on the bike's starter, engaging the engine%r[space(6)][ljust(dri <direction>,21,.)]Drives the bike <direction>. Can be a string%r[space(6)][ljust(brake,21,.)]Slams the bike's brakes on really hard%r[space(6)][ljust(sbrake,21,.)]Slowly applies the bike's brakes%r[space(6)][ljust(idle,21,.)]Drops the bike's engine from in gear to neutral%r[space(6)][ljust(station,21,.)]Drives the bike to the station%r[space(6)][ljust(scan,21,.)]Scans the room the bike is currently in%r[space(6)][ljust(scan <object>,21,.)]Scans an <object> in the same room as the bike%r[space(6)][ljust(stop,21,.)]Cuts of the bikes engine, braking if needed%r[space(6)][ljust(siren <on/off>,21,.)]To turn the sirens on or off%r[space(6)][ljust(lights <on/off>,21,.)]To turn on just the red-and-blue lights%r[space(6)][ljust(flash,21,.)]To flash the red-and-blue lights in warning%r%rNote: The bike can be either off, on but not moving, or on and moving. Each%r[space(6)]command will respond differently depending on the status of the bike.%r%r[repeat(-,78)]
&CREDITS Police Motorcycle=$credits:@pemit %#=Based on Patrol Car by APDbldr@Masq and Motorcycle Code by Sid@The Damned. Modifications and additions by Bladerunner@Cajun and Mephisto@Cajun and American Maid@Denver.
&FOLLOW Police Motorcycle=
@lock/EnterLock Police Motorcycle=+Name:DPD Badge
&BIKENAME Police Motorcycle=PMP Police Motorcycle Parent
@set Police Motorcycle=AUDIBLE
@set Police Motorcycle=ENTER_OK
@set Police Motorcycle=COMMANDS
@set Police Motorcycle=MONITOR
@set Police Motorcycle=PARENT_OK
@set Police Motorcycle=TERSE

@create DPD Badge
@lock DPD Badge==me
@desc DPD Badge=Describe me and change the @lock/EnterLock of the motorcycle to change the name of the badge required.

mchelp